Messages

61

Game Design / Re: Ideas for stage effect.

« on: October 05, 2015, 07:13:00 AM »

Make sound effects echo a bit

62

Gameplay & Discussion / Re: Introducing Delicious-Fruit.com!

« on: October 05, 2015, 07:10:01 AM »

Any chance we can make it so the author can indicate the current version of their game which would display on the page and then add a page like https://www.delicious-fruit.com/ratings/game_version.php?id=15472 which would return just the current version number? This would let us check the game's current version whenever the player launches the game so we can tell them if they need to update or not.

63

Help, Suggestions & Feedback / Re: unable to send PMs

« on: October 01, 2015, 12:15:07 PM »

For a list of possible answers check here https://www.delicious-fruit.com/ratings/full.php?s=i+wanna+be+the
 

64

General Discussion / Re: GamMaker Studio Pro in Humble Weekly Bundle for $6

« on: September 18, 2015, 09:10:59 AM »

Yar, their servers are getting wrecked right now. I managed to create and activate an account but haven't been able to log in.

65

General Discussion / GamMaker Studio Pro in Humble Weekly Bundle for $6

« on: September 17, 2015, 06:53:47 PM »

or $12 to include the Android module

httpss://www.humblebundle.com/weekly

Go nuts people

66

Unfinished / Incomplete / Re: I Wanna Be The Rex - Early Alpha

« on: July 11, 2015, 02:43:30 PM »

Since I've last updated this thread I have added stage and boss 4.

Since watching some early yosniper constest feedback I've put some work into removing or toning down anything that could be considered bullshit. The game is still trap heavy because that's the style game i wanted to make but any parts that are still 'dangerous' have been marked with danger signs. There is a new boss 1 sprite and new voice over for boss entry rooms.

I'd really appreciate any feedback (including screenshots or video) of parts of the game that still include unfair triggers.

httpss://www.dropbox.com/s/an94het4w9ef9qn/IWannaBeTheRex.zip?dl=0

67

Programming Questions / Re: Problems with creating this shape

« on: June 29, 2015, 11:17:28 AM »

Keep in mind that objects created in code will use the depth of the object that is running the code and not the depth set in the spawned object properties.

68

Programming Questions / Re: Problems with creating this shape

« on: June 29, 2015, 07:30:20 AM »

Make sure the tiles have a higher depth value than the object running the code that is creating the fruit.

69

Programming Questions / Re: Weird DeathTime Error

« on: June 27, 2015, 03:59:58 PM »

It looks like the array indexing got removed from both.
Try these

Code: [Select]

//�o�C�i���`����Ž��S��”‚�Œo��Ž���‚��‘�
var f,i,tem;
f = file_bin_open("DeathTime",1);
for(i = 1; i <= 3; i += 1){
 
  tem = global.death[i];
  file_bin_write_byte(f,floor(tem/1000000));
  tem -= floor(tem/1000000)*1000000;
  file_bin_write_byte(f,floor(tem/10000));
  tem -= floor(tem/10000)*10000;
  file_bin_write_byte(f,floor(tem/100));
  tem -= floor(tem/100)*100;
  file_bin_write_byte(f,tem);
 
  tem = global.time[i];
  file_bin_write_byte(f,floor(tem/1000000));
  tem -= floor(tem/1000000)*1000000;
  file_bin_write_byte(f,floor(tem/10000));
  tem -= floor(tem/10000)*10000;
  file_bin_write_byte(f,floor(tem/100));
  tem -= floor(tem/100)*100;
  file_bin_write_byte(f,tem);
 
  tem = global.microtime[i];
  file_bin_write_byte(f,floor(tem/1000000));
  tem -= floor(tem/1000000)*1000000;
  file_bin_write_byte(f,floor(tem/10000));
  tem -= floor(tem/10000)*10000;
  file_bin_write_byte(f,floor(tem/100));
  tem -= floor(tem/100)*100;
  file_bin_write_byte(f,tem);
}
file_bin_write_byte(f,global.L);
file_bin_write_byte(f,global.R);
file_bin_write_byte(f,global.stopMusic);
file_bin_close(f);


Code: [Select]

var f,i;
if(file_exists("DeathTime") == false){
  f = file_bin_open("DeathTime",1);
  for(i = 1; i <= 3; i += 1){
   
    file_bin_write_byte(f,global.death[i]);
    file_bin_write_byte(f,global.death[i]);
    file_bin_write_byte(f,global.death[i]);
    file_bin_write_byte(f,global.death[i]);
   
    file_bin_write_byte(f,global.time[i]);
    file_bin_write_byte(f,global.time[i]);
    file_bin_write_byte(f,global.time[i]);
    file_bin_write_byte(f,global.time[i]);
   
    file_bin_write_byte(f,global.microtime[i]);
    file_bin_write_byte(f,global.microtime[i]);
    file_bin_write_byte(f,global.microtime[i]);
    file_bin_write_byte(f,global.microtime[i]);
  }
  file_bin_close(f);
}else{
  f = file_bin_open("DeathTime",0);
  for(i = 1; i <= 3; i += 1){
   
    global.death[i] = file_bin_read_byte(f)*1000000;
    global.death[i] += file_bin_read_byte(f)*10000;
    global.death[i] += file_bin_read_byte(f)*100;
    global.death[i] += file_bin_read_byte(f);
   
    global.time[i] = file_bin_read_byte(f)*1000000;
    global.time[i] += file_bin_read_byte(f)*10000;
    global.time[i] += file_bin_read_byte(f)*100;
    global.time[i] += file_bin_read_byte(f);
   
    global.microtime[i] = file_bin_read_byte(f)*1000000;
    global.microtime[i] += file_bin_read_byte(f)*10000;
    global.microtime[i] += file_bin_read_byte(f)*100;
    global.microtime[i] += file_bin_read_byte(f);
  }
global.L = file_bin_read_byte(f);
global.R = file_bin_read_byte(f);
global.music = file_bin_read_byte(f);
  file_bin_close(f);
}


70

Game Design / Re: WetWookie's Avoidance Scripts

« on: June 24, 2015, 07:56:26 PM »

added draw square and apply gravity

71

Game Design / Re: YoSniper's Fangame Contest 2015 *NOW ACCEPTING*

« on: June 24, 2015, 04:52:49 PM »

I know it depends on how many more games come in and how long they all are but is there a loose time frame for how long we hope judging to take?

72

Game Design / Re: YoSniper's Fangame Contest 2015 *NOW ACCEPTING*

« on: June 23, 2015, 07:47:39 PM »

yosniper, the best I can suggest is to try it on another pc. If it does the same exact thing then we know it's most likely changing or adding a file somewhere wierd (like appdata) and failing when it tries to do so a second time and the file already exists\contains bad data.

73

Game Design / WetWookie's Avoidance Scripts

« on: June 23, 2015, 07:44:46 PM »

I did the thing so you don't have to

All of the draw scripts allow you to 'tag' the objects you create. You can then submit those tags to the manipulation scripts so they only affect the objects you tagged with the same value. For example you can draw a star of cherries with tag of 1 and a circle of cherries with a tag of 2 and then explode all cherries with a tag of 1 while leaving the cherries with a tag of 2 untouched. Also I recommend using objects with the sprite origin set to the center. If you don't things will look weird when you start changing your image_angle.

Drawing Shapes

draw_object_line(x1,y1,x2,y2,NumberOfObjectsInLine,ObjectOrientation,ObjectType,Tag);
Draws a line of objects

ex. draw_object_line(room_width/2-200, room_height/2, room_width/2+200, room_height/2, 10, 0, cherry,1);

(click to show/hide)

ObjectOrientation = 0 - Natural sprite angle
ObjectOrientation = 1 - Pointed 'up' along axis of line
ObjectOrientation = 2 - Pointed 'down' along axis of line
Minimum of 2 objects

Code: [Select]

//WetWookie's Avoidance Scripts!
x1 = argument0;
y1 = argument1;
x2 = argument2;
y2 = argument3;
NumObjects = argument4;
ObjOrient = argument5; // 0 = up, 1 = out, 2 = in
Object = argument6
OTag = argument7
if NumObjects < 2 {NumObjects = 2;}
if x1 == x2
{
    if y2 < y1
    {
        xt = x1;
        yt = y1;
        x1 = x2;
        y1 = y2;
        x2 = xt;
        y2 = yt;
    }
   
    XStep = (x2 - x1)/(NumObjects-1);
    YStep = (y2 - y1)/(NumObjects-1);
   
    tx = x1;
    for (ty = y1; ty <= y2; ty += YStep)
    {
        a = instance_create(tx,ty,Object);
        a.tag = OTag;
        tx += XStep;
        if ObjOrient == 1
        {
            a.image_angle = point_direction(x1,y1,x2,y2)
        } else if ObjOrient == 2
        {
            a.image_angle = point_direction(x2,y2,x1,y1)
        }
    }   
} else {
    if x2 < x1
    {
        xt = x1;
        yt = y1;
        x1 = x2;
        y1 = y2;
        x2 = xt;
        y2 = yt;
    }
   
    XStep = (x2 - x1)/(NumObjects-1);
    YStep = (y2 - y1)/(NumObjects-1);
   
    ty = y1;
    for (tx = x1; tx <= x2; tx += XStep)
    {
        a = instance_create(tx,ty,Object);
        a.tag = OTag;
        ty += YStep;
        if ObjOrient == 1
        {
            a.image_angle = point_direction(x1,y1,x2,y2)
        } else if ObjOrient == 2
        {
            a.image_angle = point_direction(x2,y2,x1,y1)
        }
    }   
}


draw_object_circle(CenterX, Centery, Radius, AngleOffset, NumberOfObjects,ObjOrientation,ObjectType,tag);
Draws a circle of objects

ex. draw_object_circle(room_width/2, room_height/2,50,0,10,1,cherry,0);

(click to show/hide)

The script will draw the first object at angle 0. If you want to rotate the circle specify an angle in AngleOffset
ObjectOrientation = 0 - Natural sprite angle
ObjectOrientation = 1 - Pointed out of the circle
ObjectOrientation = 2 - Pointed into the circle
Minimum of 4 objects

Code: [Select]

//WetWookie's Avoidance Scripts!
CenterX = argument0;
CenterY = argument1;
Radius = argument2;
AngleOffset = argument3;
NumObjects = argument4;
ObjOrient = argument5; // 0 = up, 1 = out, 2 = in
Object = argument6;
OTag = argument7;
if NumObjects < 4 { NumObjects = 4; }
AngleBetween = 360/NumObjects;
for (i = 0; i <= 360 - AngleBetween; i += AngleBetween;)
{
    AAngle = i + AngleOffset;
    ax = CenterX + cos(degtorad(AAngle)) * Radius;
    ay = CenterY - sin(degtorad(AAngle)) * Radius;
    a = instance_create(ax,ay,Object);
    a.tag = OTag;
    if ObjOrient == 1
    {
        a.image_angle = AAngle - 90;
    } else if ObjOrient == 2
    {
        a.image_angle = AAngle + 90;
    }
}


draw_object_star(CenterX,Centery,Radius,NumArms,ArmLength,AngleOffset,NumObjectsPerArm,ObjOrientation,ObjectType,tag);
Draws a star of objects

ex. draw_object_star(room_width/2, room_height/2,75,5,70,0,7,0,cherry,1);

(click to show/hide)

The script will draw the star with a 'crotch' down. If you want to rotate the star specify an angle in AngleOffset
ObjectOrientation = 0 - Natural sprite angle
ObjectOrientation = 1 - Pointed out of the star
ObjectOrientation = 2 - Pointed into the star
Minimum three objects per arm

Code: [Select]

//WetWookie's Avoidance Scripts!
CenterX = argument0;
CenterY = argument1;
Radius = argument2;
NumArms = argument3;
ArmLength = argument4;
AngleOffset = argument5;
NumObjectsPerArm = argument6;
ObjOrient = argument7; // 0 = up, 1 = out, 2 = in
Object = argument8;
OTag = argument9;


if NumObjectsPerArm < 3 { NumObjectsPerArm = 3; }
if NumObjectsPerArm mod 2 == 0 { NumObjectsPerArm += 1; }

AngleBetweenArms = 360/NumArms;
AngleBetweenObjects = AngleBetweenArms/NumObjectsPerArm;
DistBetweenArmObjs = ArmLength / floor(NumObjectsPerArm /2);

AngleOffset -= 90 - AngleBetweenObjects / 2; // Naturally angle star 'crotch' down

for (i = 0; i < NumArms; i += 1;)
{
    for (j = 0; j < floor(NumObjectsPerArm /2); j +=1)
    {
        AAngle = i * AngleBetweenArms + j * AngleBetweenObjects + AngleOffset;
        ax = CenterX + cos(degtorad(AAngle)) * (Radius + j * DistBetweenArmObjs);
        ay = CenterY - sin(degtorad(AAngle)) * (Radius + j * DistBetweenArmObjs);
        a = instance_create(ax,ay,Object);
        a.tag = OTag;
        if ObjOrient == 1
        {
            a.image_angle = AAngle - 90;
        } else if ObjOrient == 2
        {
            a.image_angle = AAngle + 90;
        }
    }
    AAngle = i * AngleBetweenArms + floor(NumObjectsPerArm /2) * AngleBetweenObjects + AngleOffset;
    ax = CenterX + cos(degtorad(AAngle)) * (Radius + ArmLength);
    ay = CenterY - sin(degtorad(AAngle)) * (Radius + ArmLength);
    a = instance_create(ax,ay,Object);
    a.tag = OTag;
    if ObjOrient == 1
    {
        a.image_angle = AAngle - 90;
    } else if ObjOrient == 2
    {
        a.image_angle = AAngle + 90;
    }
    for (j = floor(NumObjectsPerArm /2) + 1; j < NumObjectsPerArm; j +=1)
    {
        AAngle = i * AngleBetweenArms + j * AngleBetweenObjects + AngleOffset;
        ax = CenterX + cos(degtorad(AAngle)) * (Radius + (NumObjectsPerArm-1 - j) * DistBetweenArmObjs);
        ay = CenterY - sin(degtorad(AAngle)) * (Radius + (NumObjectsPerArm-1 - j) * DistBetweenArmObjs);
        a = instance_create(ax,ay,Object);
        a.tag = OTag;
        if ObjOrient == 1
        {
            a.image_angle = AAngle - 90;
        } else if ObjOrient == 2
        {
            a.image_angle = AAngle + 90;
        }
    }
   
}


draw_object_square(CenterX, CenterY ,SideLength,ObjectsPerSide,AngleOffset,ObjectOrientation,ObjectType,tag);
Draws a square

draw_object_square(room_width/2-150, room_height/2 ,250,10,0,0,cherry,0);
draw_object_square(room_width/2+150, room_height/2 ,200,10,0,0,cherry,1);
draw_object_square(room_width/2+150, room_height/2 ,200,10,45,0,cherry,1);

(click to show/hide)

Code: [Select]

//WetWookie's Avoidance Scripts!
CenterX = argument0;
CenterY = argument1;
LengthOfSide = argument2;
NumObjectsPerSide = argument3;
AngleOffset = argument4;
ObjOrient = argument5; // 0 = up, 1 = out, 2 = in
Object = argument6;
OTag = argument7;

if NumObjectsPerSide < 3 { NumObjectsPerSide = 3; }

CenterToCorner = sqrt(2 * sqr(LengthOfSide)) / 2;
CenterToModifiedCorner = sqrt(sqr(LengthOfSide / 2) + sqr((LengthOfSide/2) - LengthOfSide / (NumObjectsPerSide-1)));
ModifiedAngle = radtodeg(arccos((LengthOfSide/2)/CenterToModifiedCorner)) + AngleOffset ;

x1 = CenterX + cos(degtorad(ModifiedAngle)) * CenterToModifiedCorner;
y1 = CenterY - sin(degtorad(ModifiedAngle)) * CenterToModifiedCorner;
x2 = CenterX + cos(degtorad(-45 + AngleOffset)) * CenterToCorner;
y2 = CenterY - sin(degtorad(-45 + AngleOffset)) * CenterToCorner;
draw_object_line(x1,y1,x2,y2,NumObjectsPerSide -1,ObjOrient,Object,OTag);
x1 = CenterX + cos(degtorad(ModifiedAngle + 90)) * CenterToModifiedCorner;
y1 = CenterY - sin(degtorad(ModifiedAngle + 90)) * CenterToModifiedCorner;
x2 = CenterX + cos(degtorad(-45 + AngleOffset + 90)) * CenterToCorner;
y2 = CenterY - sin(degtorad(-45 + AngleOffset + 90)) * CenterToCorner;
draw_object_line(x1,y1,x2,y2,NumObjectsPerSide - 1,ObjOrient,Object,OTag);
x1 = CenterX + cos(degtorad(ModifiedAngle + 180)) * CenterToModifiedCorner;
y1 = CenterY - sin(degtorad(ModifiedAngle + 180)) * CenterToModifiedCorner;
x2 = CenterX + cos(degtorad(-45 + AngleOffset + 180)) * CenterToCorner;
y2 = CenterY - sin(degtorad(-45 + AngleOffset + 180)) * CenterToCorner;
draw_object_line(x1,y1,x2,y2,NumObjectsPerSide - 1,ObjOrient,Object,OTag);
x1 = CenterX + cos(degtorad(ModifiedAngle + 270)) * CenterToModifiedCorner;
y1 = CenterY - sin(degtorad(ModifiedAngle + 270)) * CenterToModifiedCorner;
x2 = CenterX + cos(degtorad(-45 + AngleOffset + 270)) * CenterToCorner;
y2 = CenterY - sin(degtorad(-45 + AngleOffset + 270)) * CenterToCorner;
draw_object_line(x2,y2,x1,y1,NumObjectsPerSide - 1,ObjOrient,Object,OTag);




Object Manipulation

explode_objects(CenterX, CenterY, ObjectSpeed, ObjectOrientation,ObjectType,tag);
Causes all matching objects to move away from CenterX,CenterY
ex. explode_objects(room_width/2,room_height/2,4,1,cherry,1);

(click to show/hide)

ObjectOrientation = 0 - Unchanged sprite angle
ObjectOrientation = 1 - Pointed 'up' along direction of travel

Code: [Select]

//WetWookie's Avoidance Scripts!
CenterX = argument0;
CenterY = argument1;
ObjSpeed = argument2;
ObjOrient = argument3; // 0 = unchanged, 1 = out
ObjectType = argument4;
OTag = argument5;

with ObjectType
{
    if tag == other.OTag
    {
        direction = point_direction(other.CenterX, other.CenterY, x, y);
        speed = other.ObjSpeed;
        if other.ObjOrient == 1
        {
            image_angle = direction - 90;
        }
    }
}


implode_objects(CenterX,CenterY,ObjectSpeed,ObjectOrientation,ObjectType,tag);
Causes all matching objects to move towards CenterX,CenterY
ex. implode_objects(room_width/2,room_height/2,4,1,cherry,1);

(click to show/hide)

ObjectOrientation = 0 - Unchanged sprite angle
ObjectOrientation = 1 - Pointed 'up' along direction of travel

Code: [Select]

//WetWookie's Avoidance Scripts!
CenterX = argument0;
CenterY = argument1;
ObjSpeed = argument2;
ObjOrient = argument3; // 0 = unchanged, 1 = out
ObjectType = argument4;
OTag = argument5;

with ObjectType
{
    if tag == other.OTag
    {
        direction = point_direction(x,y,other.CenterX, other.CenterY);
        speed = other.ObjSpeed;
        if other.ObjOrient == 1
        {
            image_angle = direction - 90;
        }
    }
}


group_move_objects(TargetX, TargetY, ObjectSpeed, ObjectOrient, ObjectType, tag)
Moves entire group of objects as one unit toward the target without breaking their shape
ex. group_move_objects(player.x,player.y,4,1,cherry,1);

(click to show/hide)

ObjectOrientation = 0 - Unchanged sprite angle
ObjectOrientation = 1 - Pointed 'up' along direction of travel

Code: [Select]

//WetWookie's Avoidance Scripts!
TargetX = argument0;
TargetY = argument1;
ObjSpeed = argument2;
ObjOrient = argument3; // 0 = unchanged, 1 = out
ObjectType = argument4;
OTag = argument5;

SumX = 0;
SumY = 0;
CountObj = 0;

with ObjectType
{
    other.SumX += x;
    other.SumY += y;
    other.CountObj += 1;
}

CenterX = SumX / CountObj;
CenterY = SumY / CountObj;

with ObjectType
{
    if tag == other.OTag
    {
        direction = point_direction(other.CenterX, other.CenterY, other.TargetX, other.TargetY);
        speed = other.ObjSpeed;
        if other.ObjOrient == 1
        {
            image_angle = direction - 90;
        }
    }
}


apply_gravity(GravValue, ImageOrient, ObjectType,tag)
Gives matching objects gravity
apply_gravity(0.4,1,cherry,1);

(click to show/hide)

Code: [Select]

//WetWookie's Avoidance Scripts!
ObjGravity = argument0;
ObjOrient = argument1; // 0 = unchanged, 1 = out
ObjectType = argument2;
OTag = argument3;

with ObjectType
{
    if tag == other.OTag
    {
        gravity = other.ObjGravity
    }
}


Feel free to point out errors, request shapes and manipulations and submit your own scripts.

74

Programming Questions / Re: Problems with creating this shape

« on: June 21, 2015, 09:28:01 AM »

I put something together that should be more accurate with larger shapes, gives you more control and should be useful for other things as well. I present to you draw_object_line(x1,x2,y1,y2, NumObjects, ObjectType)

put this in a script called draw_object_line

Code: [Select]

x1 = argument0;
y1 = argument1;
x2 = argument2;
y2 = argument3;
NumObjects = argument4;
Object = argument5

if NumObjects < 2 {NumObjects = 2;}

if x1 == x2
{
    if y2 < y1
    {
        xt = x1;
        yt = y1;
        x1 = x2;
        y1 = y2;
        x2 = xt;
        y2 = yt;
    }
   
    XStep = (x2 - x1)/(NumObjects-1);
    YStep = (y2 - y1)/(NumObjects-1);
   
    tx = x1;
    for (ty = y1; ty <= y2; ty += YStep)
    {
        a = instance_create(tx,ty,Object);
        tx += XStep;
    }   

} else {

    if x2 < x1
    {
        xt = x1;
        yt = y1;
        x1 = x2;
        y1 = y2;
        x2 = xt;
        y2 = yt;
    }
   
    XStep = (x2 - x1)/(NumObjects-1);
    YStep = (y2 - y1)/(NumObjects-1);
   
    ty = y1;
    for (tx = x1; tx <= x2; tx += XStep)
    {
        a = instance_create(tx,ty,Object);
        ty += YStep;
    }   

}

Now your shape drawing code looks pretty much the same as your starting code.
//stepcounter coding beforehand and bla
xx=room_width/2;
yy=room_height/2;
dist=50;
num=4;
for(i=-num;i<=num;i+=1){
    draw_object_line(xx,yy+i*dist,xx+(num-abs(i))*dist,yy,5,cherry);
    draw_object_line(xx,yy+i*dist,xx-(num-abs(i))*dist,yy,5,cherry);
}

This should look familiar


//stepcounter coding beforehand and bla
xx=room_width/2;
yy=room_height/2;
dist=25;
num=10;
for(i=-num;i<=num;i+=1){
    draw_object_line(xx,yy+i*dist,xx+(num-abs(i))*dist,yy,num * 10,bullet);
    draw_object_line(xx,yy+i*dist,xx-(num-abs(i))*dist,yy,num * 10,bullet);
}

75

Programming Questions / Re: Problems with creating this shape

« on: June 20, 2015, 10:57:10 PM »

//stepcounter coding beforehand and bla
xx=room_width/2;
yy=room_height/2;
dist=50;
num=4;
for(i=-num;i<=num;i+=1){
    for(j=-num;j<=num;j+=1){
        xp = xx + (i *(abs(abs(j)-num)/num)) *dist;
        yp = yy + (j *(abs(abs(i)-num)/num)) *dist;
        a=instance_create(xp,yp,cherry);
    }
}